Relay-Version: version B 2.10 5/3/83; site utzoo.UUCP
Posting-Version: version B 2.10.1 6/24/83; site druxp.UUCP
Path: utzoo!decvax!mcnc!akgua!whuxlm!whuxl!houxm!mtuxo!drutx!druxp!mab
From: mab@druxp.UUCP (BlandMA)
Newsgroups: net.micro.cbm
Subject: Re: ?converting a tape data file to disk file?
Message-ID: <849@druxp.UUCP>
Date: Thu, 22-Aug-85 18:14:32 EDT
Article-I.D.: druxp.849
Posted: Thu Aug 22 18:14:32 1985
Date-Received: Sat, 24-Aug-85 05:55:09 EDT
References: <5474@fortune.UUCP>
Distribution: na
Organization: AT&T Information Systems Laboratories, Denver
Lines: 38

> "load "filename",1,1   One of these programs loads starting at $C000.  The
> only method I know to save this file short of peeking and put#'in to disk is
> to use a super wedge.  Unfortunately, my wedge resides in the neighborhood of
> $C000.  I would like to find a way to transfer these two files from tape to
> disk (disk .prg format so that I can 'load "file",8,1') while including the
> loading address in the file.

I wrote the following BASIC program about a year ago to solve
a similar problem.  It calls the kernal save routine from
BASIC to save the program file.  Happy hacking! (old definition
of hacking).

100 print"----save memory to disk----":print
110 input"       start address";sa
120 input"end address plus one";ea
130 input"           file name";f$
140 a=780:x=781:y=782
150 rem -----setlfs-----
160 poke a,2
170 poke x,8
180 poke y,2
190 sys65466
200 rem -----setnam-----
210 poke a,len(f$)
220 fori=1tolen(f$):poke820+i-1,asc(mid$(f$,i,1)):next
230 poke x,52
240 poke y,3
250 sys65469
260 rem -----save-----
270 poke254,sa-int(sa/256)*256
280 poke255,int(sa/256)
290 poke a,254
300 poke x,ea-int(ea/256)*256
310 poke y,int(ea/256)
320 sys65496
330 print:printf$" saved"
-- 
Alan Bland     ihnp4!druxp!mab     AT&T-ISL  Denver, CO