Relay-Version: version B 2.10 5/3/83; site utzoo.UUCP
Posting-Version: version B 2.10 UW 5/3/83; site uw-beaver
Path: utzoo!watmath!clyde!burl!ulysses!cbosgd!cbdkc1!desoto!packard!hoxna!houxm!vax135!cornell!uw-beaver!info-mac
From: info-mac@uw-beaver (info-mac)
Newsgroups: fa.info-mac
Subject: Re: DVORAK REQUEST
Message-ID: <1802@uw-beaver>
Date: Wed, 26-Sep-84 22:15:32 EDT
Article-I.D.: uw-beave.1802
Posted: Wed Sep 26 22:15:32 1984
Date-Received: Thu, 4-Oct-84 01:56:01 EDT
Sender: daemon@uw-beave
Organization: U of Washington Computer Science
Lines: 36

From: Charlie Spitzer 
If I typed this correctly, it is a routine to change the Mac keyboard to
Dvorak.

------------------------------------------------------------

100 REM Dvorak (simplified) keyboard setup (same as //c)
110 'by Ronald H. Hicholson, Jr  CIS ID [71555,1513]
120 PRINT "Do you want your keyboard modified to Dvorak";
130 INPUT A$:IF A$<>"y" AND A$<>"Y" THEN STOP
140 DEF FNLPEEK(Z)=PEEK(Z+3)+256*(PEEK(Z+2)+256*(PEEK(Z+1)+256*PEEK(Z)))
160 ' following are the strings for qwerty,dvorak
170 '    dvorak shifted,and dvorak with caps lock
180 QWERTY$="asdfgzxcv~bqwert12345=97-80]ou[ip~ljk'k;\,/nm."
190 DVORAK$="aoeudi;qjk~x',.pfy123465=97]80{rg/cl~nh-ts\wzbmv"
200 DVORSH$="AOEUDI:QJK~X',.PFY!@#$^%+(&[*)}RG?CL~NH_TS|WZBMV"
210 DVORCL$="AOEUDI;QJK~X',.PFY123465=97]80{RG/CL~NH-TS\WZBMV"
220 MID$(DVORSH$,13,1)=CHR$(34):REM place DBL.QUOTA in string
230 MID$(DVORAK$,37,1)=CHR$(13):REM place CR in string
240 MID$(DVORSH$,37,1)=CHR$(13):REM place CR in string
250 MID$(DVORCL$,37,1)=CHR$(13):REM place CR in string
260 '
270 '  find "asdf" KEYC package
280 P=&H2500
290 WHILE FNLPEEK(P)<>(65536|*&H6173+&H6466)
300   P=P+2:WEND
310 IF FNLPEEK(P+&H35)<>(65536!*&H4153+&H4446) THEN P=P+2:GOTO 290
320 '
330 ' install dvorak @ P
340 FOR I=0 TO &H2F:POKE (P+I),ASC(MID$(DVORAK$,I+1,1)):NEXT I
350 FOR I=0 TO &H2F:POKE (P+&H35+I),ASC(MID$(DVORSH$,I+1,1)):NEXT I
360 FOR I=0 TO &H2F:POKE (P+&H6a+I),ASC(MID$(DVIRCL$,I+1,1)):NEXT I
370 PRINT "done"
380 PRINT "Select Key Caps from Menu for help."
385 PRINT "Reset gets you back to QWERTY"
390 END