Megalextoria
Retro computing and gaming, sci-fi books, tv and movies and other geeky stuff.

Home » Digital Archaeology » Computer Arcana » Apple » Apple II » Recap of my ProDOS /// ideas
Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend 
Switch to threaded view of this topic Create a new topic Submit Reply
Recap of my ProDOS /// ideas [message #386520] Thu, 29 August 2019 05:29 Go to next message
Steve Nickolas is currently offline  Steve Nickolas
Messages: 1883
Registered: October 2012
Karma: 0
Senior Member
Since there's actual work being done on an Apple /// port of ProDOS I'll
just recap my thoughts/attempts from before. I tried to port it myself
some time ago without luck, but I hadn't even gotten a build tree for the
real thing.

So the idea was that if ProDOS could be relocated to stay out of
F800-FFFF, then a lot of software that only needed 64K and an integer ][
would work on the ///.

I created this (fits in track 00 sector D on a DOS order disk):

blok = $06
idxl = $0A
idxh = $0C
idxp = $0E
iobuff = $85

slot = $81
drive = $82
rwtscmd = $87
blockio = $F479
clrscr = $FB7D

clrscrn = $FB7D
scrn = $05AE
dostyp = $FF
sosid = $0C00
entlen = $0C23
kernel = $2000

.org $A000
entry: lda #$F0 ; set system bank to 0
sta $FFEF ; (Apple ][ compatibility)
lda #$00 ; set zero page to 00
sta $FFD0 ; (makes our life easier)
lda #$01 ; read
sta rwtscmd
lda #$00 ; set some defaults, and read the
sta iobuff ; root directory (blocks 2-5) at $0C00
sta idxl
lda #$0C
sta iobuff+1
sta idxl+1
lda #$02
jsr qrdblk ; read block 1 of 4
bcs err
ldx #$00
lda #$03
jsr qrdblk ; read block 2 of 4
bcs err
ldx #$00
lda #$04
jsr qrdblk ; read block 3 of 4
bcs err
ldx #$00
lda #$05
jsr qrdblk ; read block 4 of 4
bcc gotdir
err: jsr clrscrn ; basic "display message and hang"
ldy #meslen
@1: lda ermsg, y
sta scrn, y
dey
bpl @1
@2: bmi @2 ; ALWAYS

gotdir: lda sosid ; most of the code which follows is
ora sosid+1 ; taken directly from ProDOS-8, with
bterr1: bne err ; most comments intact.
lda #$04
bne nxdent1 ; ALWAYS
nxdent: lda idxl
nxdent1: clc
adc entlen ; bump to next directory entry
tay
bcc nxdent2
inc idxl+1
lda idxl+1 ; check for new block
lsr ; if even then new block
bcs nxdent2
cmp #$0A ; have all filenames been compared?
beq err
ldy #$04 ; new start of block
nxdent2: sty idxl ; NOTE: this method treats junk at end
lda sysname ; of block as an entry
and #$0F
tay
lookpro: lda (idxl), y ; look for matching name
cmp sysname, y ; last-to-first method
bne nxdent ; branch if no match
dey ; else check all characters
bpl lookpro ; including length/storage type
and #$F0 ; make sure storage type is TREE
cmp #$20
bne err
ldy #$10 ; get filetype and index block address
lda (idxl), y
cmp #dostyp ; is it a SYS file?
bne err
iny
lda (idxl), y
sta blok
iny
lda (idxl), y
sta blok+1
lda #$00 ; now set up to read kernel
sta idxl
ldy #$1E ; read index block at $1E00 and
sty idxl+1 ; kernel at $2000
sty iobuff+1
iny
sty idxh+1
rdkernl: tya
pha
lda blok
ldx blok+1
jsr blockio
bcs err
pla
tay
inc iobuff+1
inc iobuff+1
ldy idxp
inc idxp
lda (idxl), y
sta blok
lda (idxh), y
sta blok+1
ora (idxl), y
bne rdkernl
jmp kernel
qrdblk: ldx #$00
jsr blockio
inc iobuff+1
inc iobuff+1
rts

sysname: .byte $27, "PRODOS3 "
meslen = 28
ermsg: .byte $AA, $AA, $AA, $A0, $D5, $CE, $C1, $C2
.byte $CC, $C5, $A0, $D4, $CF, $A0, $CC, $CF
.byte $C1, $C4, $A0, $D0, $D2, $CF, $C4, $CF
.byte $D3, $A0, $AA, $AA, $AA

.res $A100-*

And indeed, this will load a SYS file called PRODOS3 into memory at 2000
and execute it. It's not fast, but it works. (I mentioned this after
testing the ProDOS 2.5 bootloader on MAME's Apple /// emulation and
getting weird results - but I don't know what that's trying to do.)

Keep in mind: I've actually written stuff that will load the font and the
monitor on the ///, and doesn't step on the hardware (I patched the
monitor for this). This is the "Star Emulator" stuff.

I would be curious just how much software this could coax into working.

-uso.
Re: Recap of my ProDOS /// ideas [message #386523 is a reply to message #386520] Thu, 29 August 2019 07:14 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: John Brooks

On Thursday, August 29, 2019 at 2:29:19 AM UTC-7, Steve Nickolas wrote:
> Since there's actual work being done on an Apple /// port of ProDOS I'll
> just recap my thoughts/attempts from before. I tried to port it myself
> some time ago without luck, but I hadn't even gotten a build tree for the
> real thing.
>
> So the idea was that if ProDOS could be relocated to stay out of
> F800-FFFF, then a lot of software that only needed 64K and an integer ][
> would work on the ///.
>
> I created this (fits in track 00 sector D on a DOS order disk):
>
> blok = $06
> idxl = $0A
> idxh = $0C
> idxp = $0E
> iobuff = $85
>
> slot = $81
> drive = $82
> rwtscmd = $87
> blockio = $F479
> clrscr = $FB7D
>
> clrscrn = $FB7D
> scrn = $05AE
> dostyp = $FF
> sosid = $0C00
> entlen = $0C23
> kernel = $2000
>
> .org $A000
> entry: lda #$F0 ; set system bank to 0
> sta $FFEF ; (Apple ][ compatibility)
> lda #$00 ; set zero page to 00
> sta $FFD0 ; (makes our life easier)
> lda #$01 ; read
> sta rwtscmd
> lda #$00 ; set some defaults, and read the
> sta iobuff ; root directory (blocks 2-5) at $0C00
> sta idxl
> lda #$0C
> sta iobuff+1
> sta idxl+1
> lda #$02
> jsr qrdblk ; read block 1 of 4
> bcs err
> ldx #$00
> lda #$03
> jsr qrdblk ; read block 2 of 4
> bcs err
> ldx #$00
> lda #$04
> jsr qrdblk ; read block 3 of 4
> bcs err
> ldx #$00
> lda #$05
> jsr qrdblk ; read block 4 of 4
> bcc gotdir
> err: jsr clrscrn ; basic "display message and hang"
> ldy #meslen
> @1: lda ermsg, y
> sta scrn, y
> dey
> bpl @1
> @2: bmi @2 ; ALWAYS
>
> gotdir: lda sosid ; most of the code which follows is
> ora sosid+1 ; taken directly from ProDOS-8, with
> bterr1: bne err ; most comments intact.
> lda #$04
> bne nxdent1 ; ALWAYS
> nxdent: lda idxl
> nxdent1: clc
> adc entlen ; bump to next directory entry
> tay
> bcc nxdent2
> inc idxl+1
> lda idxl+1 ; check for new block
> lsr ; if even then new block
> bcs nxdent2
> cmp #$0A ; have all filenames been compared?
> beq err
> ldy #$04 ; new start of block
> nxdent2: sty idxl ; NOTE: this method treats junk at end
> lda sysname ; of block as an entry
> and #$0F
> tay
> lookpro: lda (idxl), y ; look for matching name
> cmp sysname, y ; last-to-first method
> bne nxdent ; branch if no match
> dey ; else check all characters
> bpl lookpro ; including length/storage type
> and #$F0 ; make sure storage type is TREE
> cmp #$20
> bne err
> ldy #$10 ; get filetype and index block address
> lda (idxl), y
> cmp #dostyp ; is it a SYS file?
> bne err
> iny
> lda (idxl), y
> sta blok
> iny
> lda (idxl), y
> sta blok+1
> lda #$00 ; now set up to read kernel
> sta idxl
> ldy #$1E ; read index block at $1E00 and
> sty idxl+1 ; kernel at $2000
> sty iobuff+1
> iny
> sty idxh+1
> rdkernl: tya
> pha
> lda blok
> ldx blok+1
> jsr blockio
> bcs err
> pla
> tay
> inc iobuff+1
> inc iobuff+1
> ldy idxp
> inc idxp
> lda (idxl), y
> sta blok
> lda (idxh), y
> sta blok+1
> ora (idxl), y
> bne rdkernl
> jmp kernel
> qrdblk: ldx #$00
> jsr blockio
> inc iobuff+1
> inc iobuff+1
> rts
>
> sysname: .byte $27, "PRODOS3 "
> meslen = 28
> ermsg: .byte $AA, $AA, $AA, $A0, $D5, $CE, $C1, $C2
> .byte $CC, $C5, $A0, $D4, $CF, $A0, $CC, $CF
> .byte $C1, $C4, $A0, $D0, $D2, $CF, $C4, $CF
> .byte $D3, $A0, $AA, $AA, $AA
>
> .res $A100-*
>
> And indeed, this will load a SYS file called PRODOS3 into memory at 2000
> and execute it. It's not fast, but it works. (I mentioned this after
> testing the ProDOS 2.5 bootloader on MAME's Apple /// emulation and
> getting weird results - but I don't know what that's trying to do.)
>
> Keep in mind: I've actually written stuff that will load the font and the
> monitor on the ///, and doesn't step on the hardware (I patched the
> monitor for this). This is the "Star Emulator" stuff.
>
> I would be curious just how much software this could coax into working.
>
> -uso.

Hi Uso. The initial requirement for the new P8 2.5 boot blocks was to be able to load PRODOS from root directories with >51 files since 2.5 allows expanding the root dir beyond 4 blocks.

P8 2.5 loader features:
1) Will find PRODOS in root dir blocks anywhere on device (not limited to blocks 2-5)
2) Boots & loads PRODOS on Apple ///
3) Displays a loading progress bar while booting
4) Performs error timeout and retry for disks with read errors
5) Reports numerical errors during boot if the disk media fails to read
6) Has on-the-fly 6&2 decode in 29 cycles == works on +/- 5% RPM drives per Apple spec
7) Supports a high-density 5.25 format with more tracks and blocks-per-track
8) Planned support for booting >32MB volumes

What Apple /// boot problems did you encounter? I worked with Martin Hayes last year on the Apple /// boot code and verified the loader would boot on a physical Apple ///, but there could have been regressions due to more recent changes.

Ultimately, I'd like to get a relocating loader and memory manager into ProDOS so it can relocate to other memory banks and restore application access to the upper 12KB on Apple II and Apple /// machines.

-JB
Re: Recap of my ProDOS /// ideas [message #386524 is a reply to message #386523] Thu, 29 August 2019 07:38 Go to previous messageGo to next message
Steve Nickolas is currently offline  Steve Nickolas
Messages: 1883
Registered: October 2012
Karma: 0
Senior Member
On Thu, 29 Aug 2019, John Brooks wrote:

> Hi Uso. The initial requirement for the new P8 2.5 boot blocks was to be able to load PRODOS from root directories with >51 files since 2.5 allows expanding the root dir beyond 4 blocks.
>
> P8 2.5 loader features:
> 1) Will find PRODOS in root dir blocks anywhere on device (not limited to blocks 2-5)
> 2) Boots & loads PRODOS on Apple ///
> 3) Displays a loading progress bar while booting
> 4) Performs error timeout and retry for disks with read errors
> 5) Reports numerical errors during boot if the disk media fails to read
> 6) Has on-the-fly 6&2 decode in 29 cycles == works on +/- 5% RPM drives per Apple spec
> 7) Supports a high-density 5.25 format with more tracks and blocks-per-track
> 8) Planned support for booting >32MB volumes
>
> What Apple /// boot problems did you encounter? I worked with Martin
> Hayes last year on the Apple /// boot code and verified the loader would
> boot on a physical Apple ///, but there could have been regressions due
> to more recent changes.

This doesn't seem right, unless I'm not making a proper assumption here:

https://i.imgur.com/3vI7HX6.png

> Ultimately, I'd like to get a relocating loader and memory manager into
> ProDOS so it can relocate to other memory banks and restore application
> access to the upper 12KB on Apple II and Apple /// machines.

I'm not sure adding 48K support will be particularly useful. :o

I'd been playing around with ideas, like trying to patch ProDOS to use a
Saturn memory card to provide FPBASIC to an Integer ][, but I generally
didn't have the luck in getting it to work. (Pilot error, no doubt)

I think my ProDOS ideas were a lot less complicated than yours ;) - but
still considering reattempting them.

-uso.
Re: Recap of my ProDOS /// ideas [message #386525 is a reply to message #386524] Thu, 29 August 2019 08:19 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: John Brooks

On Thursday, August 29, 2019 at 4:38:42 AM UTC-7, Steve Nickolas wrote:
> On Thu, 29 Aug 2019, John Brooks wrote:
>
>> Hi Uso. The initial requirement for the new P8 2.5 boot blocks was to be able to load PRODOS from root directories with >51 files since 2.5 allows expanding the root dir beyond 4 blocks.
>>
>> P8 2.5 loader features:
>> 1) Will find PRODOS in root dir blocks anywhere on device (not limited to blocks 2-5)
>> 2) Boots & loads PRODOS on Apple ///
>> 3) Displays a loading progress bar while booting
>> 4) Performs error timeout and retry for disks with read errors
>> 5) Reports numerical errors during boot if the disk media fails to read
>> 6) Has on-the-fly 6&2 decode in 29 cycles == works on +/- 5% RPM drives per Apple spec
>> 7) Supports a high-density 5.25 format with more tracks and blocks-per-track
>> 8) Planned support for booting >32MB volumes
>>
>> What Apple /// boot problems did you encounter? I worked with Martin
>> Hayes last year on the Apple /// boot code and verified the loader would
>> boot on a physical Apple ///, but there could have been regressions due
>> to more recent changes.
>
> This doesn't seem right, unless I'm not making a proper assumption here:
>
> https://i.imgur.com/3vI7HX6.png
>
>> Ultimately, I'd like to get a relocating loader and memory manager into
>> ProDOS so it can relocate to other memory banks and restore application
>> access to the upper 12KB on Apple II and Apple /// machines.
>
> I'm not sure adding 48K support will be particularly useful. :o
>
> I'd been playing around with ideas, like trying to patch ProDOS to use a
> Saturn memory card to provide FPBASIC to an Integer ][, but I generally
> didn't have the luck in getting it to work. (Pilot error, no doubt)
>
> I think my ProDOS ideas were a lot less complicated than yours ;) - but
> still considering reattempting them.
>
> -uso.

> This doesn't seem right, unless I'm not making a proper assumption here:

Yep, that looks broken. It got past the A3 bootstrap at $A000 and is running common code at $801, but failed to load PRODOS blocks. I'll investigate when I get a chance.

> I'm not sure adding 48K support will be particularly useful. :o

PRODOS needs to relocate into $2000-$BFFF to run in high memory banks on aux/ramworks, IIGS, and Apple ///.

-JB
Re: Recap of my ProDOS /// ideas [message #386529 is a reply to message #386525] Thu, 29 August 2019 12:51 Go to previous messageGo to next message
Steve Nickolas is currently offline  Steve Nickolas
Messages: 1883
Registered: October 2012
Karma: 0
Senior Member
On Thu, 29 Aug 2019, John Brooks wrote:

> PRODOS needs to relocate into $2000-$BFFF to run in high memory banks on
> aux/ramworks, IIGS, and Apple ///.
>
> -JB
>

That may be more flexible than my intended approach: assemble it down 2K,
then bank C800-CFFF as needed, and install a cutdown emulation environment
from F800-FFFF (plus load the font).

Though with a 1.x ProDOS base my idea would probably be more workable.

-uso.
Re: Recap of my ProDOS /// ideas [message #386533 is a reply to message #386520] Thu, 29 August 2019 15:29 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: Frank M.

Does the /// *need* to be put into ][ emulation mode? What if the boot loader set things up correctly in /// mode, before transferring control to prodos? (assuming some memory layout/ROM differences--haven't dug into the tech details yet)

As a 'new' owner of a ///, looking forward to new developments here!
Re: Recap of my ProDOS /// ideas [message #386540 is a reply to message #386533] Thu, 29 August 2019 15:40 Go to previous messageGo to next message
David Schmidt is currently offline  David Schmidt
Messages: 890
Registered: October 2012
Karma: 0
Senior Member
On 8/29/19 3:29 PM, Frank M. wrote:
> Does the /// *need* to be put into ][ emulation mode?

No, and of course you're walled off from all the /// goodness once you
do that. Emulation mode is a dead-end street.
Re: Recap of my ProDOS /// ideas [message #386544 is a reply to message #386540] Thu, 29 August 2019 19:13 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: Bobbi

On Thursday, 29 August 2019 15:40:18 UTC-4, schmidtd wrote:
> On 8/29/19 3:29 PM, Frank M. wrote:
>> Does the /// *need* to be put into ][ emulation mode?
>
> No, and of course you're walled off from all the /// goodness once you
> do that. Emulation mode is a dead-end street.

Hey, take it to comp.sys.apple3! Oh ... wait ...
Re: Recap of my ProDOS /// ideas [message #386553 is a reply to message #386544] Fri, 30 August 2019 01:27 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: Anthony Adverse

On Friday, August 30, 2019 at 9:13:07 AM UTC+10, Bobbi wrote:
> On Thursday, 29 August 2019 15:40:18 UTC-4, schmidtd wrote:
>> On 8/29/19 3:29 PM, Frank M. wrote:
>>> Does the /// *need* to be put into ][ emulation mode?
>>
>> No, and of course you're walled off from all the /// goodness once you
>> do that. Emulation mode is a dead-end street.
>
> Hey, take it to comp.sys.apple3! Oh ... wait ...

This is CSA2.5 :P
Re: Recap of my ProDOS /// ideas [message #386554 is a reply to message #386533] Fri, 30 August 2019 01:52 Go to previous messageGo to next message
Steve Nickolas is currently offline  Steve Nickolas
Messages: 1883
Registered: October 2012
Karma: 0
Senior Member
On Thu, 29 Aug 2019, Frank M. wrote:

> Does the /// *need* to be put into ][ emulation mode? What if the boot
> loader set things up correctly in /// mode, before transferring control
> to prodos? (assuming some memory layout/ROM differences--haven't dug
> into the tech details yet)
>
> As a 'new' owner of a ///, looking forward to new developments here!

I'd rather use Satan Mode than emulation mode...

Tools exist for running DOS 3.3 without locking the /// into emulation
mode - and I've written a couple.

-uso.
Re: Recap of my ProDOS /// ideas [message #386568 is a reply to message #386554] Fri, 30 August 2019 22:00 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: Frank M.

On Thursday, August 29, 2019 at 10:52:17 PM UTC-7, Steve Nickolas wrote:
> On Thu, 29 Aug 2019, Frank M. wrote:
>
>> Does the /// *need* to be put into ][ emulation mode? What if the boot
>> loader set things up correctly in /// mode, before transferring control
>> to prodos? (assuming some memory layout/ROM differences--haven't dug
>> into the tech details yet)
>>
>> As a 'new' owner of a ///, looking forward to new developments here!
>
> I'd rather use Satan Mode than emulation mode...
>
> Tools exist for running DOS 3.3 without locking the /// into emulation
> mode - and I've written a couple.
>
> -uso.


I was unaware of this potential until I googled it. I found the 2017 kfest Satan Mode (AKA Funny Mode) demonstration by Martin Haye. Unfortunately, the disk doesn't seem to come with either source code or any documentation. Ciderpress thinks it's a normal DOS 3.3 disk, but obviously something else is going on, likely with the "RESERVED1" and "RESERVED2" files. Pretty cool though.
Re: Recap of my ProDOS /// ideas [message #386569 is a reply to message #386568] Fri, 30 August 2019 23:19 Go to previous messageGo to next message
Steve Nickolas is currently offline  Steve Nickolas
Messages: 1883
Registered: October 2012
Karma: 0
Senior Member
On Fri, 30 Aug 2019, Frank M. wrote:

> On Thursday, August 29, 2019 at 10:52:17 PM UTC-7, Steve Nickolas wrote:
>> On Thu, 29 Aug 2019, Frank M. wrote:
>>
>>> Does the /// *need* to be put into ][ emulation mode? What if the boot
>>> loader set things up correctly in /// mode, before transferring control
>>> to prodos? (assuming some memory layout/ROM differences--haven't dug
>>> into the tech details yet)
>>>
>>> As a 'new' owner of a ///, looking forward to new developments here!
>>
>> I'd rather use Satan Mode than emulation mode...
>>
>> Tools exist for running DOS 3.3 without locking the /// into emulation
>> mode - and I've written a couple.
>>
>> -uso.
>
>
> I was unaware of this potential until I googled it. I found the 2017
> kfest Satan Mode (AKA Funny Mode) demonstration by Martin Haye.
> Unfortunately, the disk doesn't seem to come with either source code or
> any documentation. Ciderpress thinks it's a normal DOS 3.3 disk, but
> obviously something else is going on, likely with the "RESERVED1" and
> "RESERVED2" files. Pretty cool though.

http://3.buric.co/star051s.dsk.gz

This has a bootloader that on a /// will load the first file, if it is an
S file, and run it. It also has an S file that actually contains the code
to more-or-less emulate a ][+ without locking it down. It uses an extra
sector on track 0.

tl;dr it'll boot on both a ][+ and a ///.

-uso.
Re: Recap of my ProDOS /// ideas [message #386588 is a reply to message #386544] Sat, 31 August 2019 12:40 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: James Davis

On Thursday, August 29, 2019 at 4:13:07 PM UTC-7, Bobbi wrote:
> On Thursday, 29 August 2019 15:40:18 UTC-4, schmidtd wrote:
>> On 8/29/19 3:29 PM, Frank M. wrote:
>>> Does the /// *need* to be put into ][ emulation mode?
>>
>> No, and of course you're walled off from all the /// goodness once you
>> do that. Emulation mode is a dead-end street.
>
> Hey, take it to comp.sys.apple3! Oh ... wait ...

This forum is really for everything Apple Computer, Inc. computers--Apple ][ through Macintosh--and everything related to them.
Re: Recap of my ProDOS /// ideas [message #386597 is a reply to message #386588] Sat, 31 August 2019 20:25 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: Bobbi

On Saturday, 31 August 2019 12:40:59 UTC-4, James Davis wrote:
> On Thursday, August 29, 2019 at 4:13:07 PM UTC-7, Bobbi wrote:
>> On Thursday, 29 August 2019 15:40:18 UTC-4, schmidtd wrote:
>>> On 8/29/19 3:29 PM, Frank M. wrote:
>>>> Does the /// *need* to be put into ][ emulation mode?
>>>
>>> No, and of course you're walled off from all the /// goodness once you
>>> do that. Emulation mode is a dead-end street.
>>
>> Hey, take it to comp.sys.apple3! Oh ... wait ...
>
> This forum is really for everything Apple Computer, Inc. computers--Apple ][ through Macintosh--and everything related to them.

Haha I know. I was making a joke about us being overwhelmed by all these 1000s of Apple III users :)
Re: Recap of my ProDOS /// ideas [message #386696 is a reply to message #386533] Thu, 05 September 2019 03:46 Go to previous messageGo to next message
Anonymous
Karma:
Originally posted by: John Brooks

On Thursday, August 29, 2019 at 12:29:45 PM UTC-7, Frank M. wrote:
> Does the /// *need* to be put into ][ emulation mode? What if the boot loader set things up correctly in /// mode, before transferring control to prodos? (assuming some memory layout/ROM differences--haven't dug into the tech details yet)
>
> As a 'new' owner of a ///, looking forward to new developments here!

Frank, you were able to test ProDOS 2.5.0 alpha 3 and it is booting on your physical Apple ///, right? If you get a chance, can you also see if 2.5.0a4 will boot on your Apple ///?

Uso, I'm not sure why MAME is hanging during P8 boot when it works on physical hardware. Any idea why/where MAME is hanging?

-JB
Re: Recap of my ProDOS /// ideas [message #386703 is a reply to message #386696] Thu, 05 September 2019 10:38 Go to previous messageGo to next message
Steve Nickolas is currently offline  Steve Nickolas
Messages: 1883
Registered: October 2012
Karma: 0
Senior Member
On Thu, 5 Sep 2019, John Brooks wrote:

> Uso, I'm not sure why MAME is hanging during P8 boot when it works on
> physical hardware. Any idea why/where MAME is hanging?

Hard to tell, but it somehow seems to go off into the weeds and hit one of
the lock-up opcodes.

The jump into the weeds seems to come while coming out of ROM space during
the 801 routine. I haven't seen anything further yet.

-uso.
Re: Recap of my ProDOS /// ideas [message #386712 is a reply to message #386696] Thu, 05 September 2019 16:39 Go to previous message
Anonymous
Karma:
Originally posted by: Frank M.

On Thursday, September 5, 2019 at 12:46:26 AM UTC-7, John Brooks wrote:
> On Thursday, August 29, 2019 at 12:29:45 PM UTC-7, Frank M. wrote:
>> Does the /// *need* to be put into ][ emulation mode? What if the boot loader set things up correctly in /// mode, before transferring control to prodos? (assuming some memory layout/ROM differences--haven't dug into the tech details yet)
>>
>> As a 'new' owner of a ///, looking forward to new developments here!
>
> Frank, you were able to test ProDOS 2.5.0 alpha 3 and it is booting on your physical Apple ///, right? If you get a chance, can you also see if 2.5..0a4 will boot on your Apple ///?
>
> Uso, I'm not sure why MAME is hanging during P8 boot when it works on physical hardware. Any idea why/where MAME is hanging?
>
> -JB


a4 gets to the prodos screen and hangs. text is all uppercase and has underlines instead of lowercase. seems to get further than the a3 version though (past the bootloader). The /// date is working correctly on the splash screen. I can test NSC on ][+ but will have to dig up some hardware.

side question: is prodos /// potentially going to give the 'satan mode' graphics/sound/etc options?
  Switch to threaded view of this topic Create a new topic Submit Reply
Previous Topic: Cryptocurrency
Next Topic: ProDOS port request
Goto Forum:
  

-=] Back to Top [=-
[ Syndicate this forum (XML) ] [ RSS ] [ PDF ]

Current Time: Sun Oct 13 18:33:42 EDT 2019

Total time taken to generate the page: 0.01008 seconds