| "Atari Video Music"-style Music Visualizer [message #366131] |
Sat, 07 April 2018 12:49  |
|
|
Originally posted by: frank_o_rama
Here's a short program that takes the cassette audio input and flips between page 1 and 2 when it detects a zero-crossing, creating a visual feedback to the music. Connect your iphone/laptop/stereo to the cassette input and hit play to feed in audio. toggles the speaker on each transition to give a 1-bit version of the input. Exits on keypress. (II-series computer with cassette input only -- does not work on emulators). Enjoy!
F
;
; Apple ][ "Atari Video Music"-style Visualizer
;
; a Ghetto Music Visualizer
; for the Apple ][-series computers
; (requires a cassette input port)
;
; Frank Milliron - April 1st, 2018
; frank_o_rama@hotmail.com
;
************************************************************ ****
* VISUALIZER *
************************************************************ ****
ORG $2000 ; CALL 8192
Init JSR $FC58 ; HOME - turn page 1 black
LDA #0
STA $F0 ; zero out last reading variable
LDA #$20 ; inverse space character
LDY #$00
ClrPg2 STA $800,Y ; turn page 2 white
STA $900,Y
STA $A00,Y
STA $B00,Y
INY
BNE ClrPg2 ; loop 256 times
Input LDA $C000 ; check for keypress
BMI Exit ; yes, let's exit
LDA $C060 ; get input from cassette port
EOR $F0 ; has reading changed since last sample?
BMI Changed ; Yes
BPL Input ; No change
Changed EOR $F0 ; flip original bit back
STA $F0 ; update previous reading variable to new reading
STA $C030 ; click the speaker
SoftSw EQU *+1 ; the "55" in "$C055"
BIT $C055 ; Start showing Page 2 (self-modifying!)
LDA SoftSw
EOR #1 ; Alternate displaying page 1/2 ($C054/C055)
STA SoftSw
JMP Input ; do it again
Exit BIT $C010 ; clear keyboard strobe
BIT $C054 ; switch back to page 1
RTS ; exit
CALL-151
2000:20 58 FC A9 00 85 F0 A9
2008:20 A0 00 99 00 08 99 00
2010:09 99 00 0A 99 00 0B C8
2018:D0 F1 AD 00 C0 30 1E AD
2020:60 C0 45 F0 30 02 10 F2
2028:45 F0 85 F0 8D 30 C0 2C
2030:55 C0 AD 30 20 49 01 8D
2038:30 20 4C 1A 20 2C 10 C0
2040:2C 54 C0 60
BSAVE VISUALIZER,A$2000,L$44
2000G
|
|
|
|
|
|
Members
Search
Help
Register
Login
Home
